Wie oft kommt ein Zeichen in einer Zelle vor Excel?

Mit „Text" übergeben Sie den Text, in dem Sie ein bestimmtes Zeichen zählen möchten. Das zu zählende Zeichen legen Sie über das Argument „Zählzeichen" fest.

Excel: So einfach funktioniert die Formel zum Zählen bestimmter Zeichen einer Zelle
Die Formel kombiniert mehrere Funktionen, um zum Ziel zu gelangen:

1. Über die Funktion WECHSELN ersetzen Sie innerhalb des Textes das Zählzeichen durch nichts.
2. Von diesem verkürzten Text ermitteln Sie mit der zweiten LÄNGE-Funktion die Anzahl der Zeichen.
3. Mit der ersten LÄNGE-Funktion ermitteln Sie die Anzahl der Zeichen im ursprünglichen Text.
4. Indem Sie diese beiden Zeichenzahlen voneinander abziehen, erhalten Sie exakt die Anzahl des gesuchten Zeichens.

Wort in einem Bereich blitzschnell zählen: Wie oft kommt es vor
Nicht nur die Anzahl eines Zeichens in einer Zelle ist eine häufig benötigte Information. Für viele Aufgabenstellungen müssen Sie zählen, wie oft ein bestimmtes Wort in einem Zellbereich auftritt. Diese Aufgabenstellung lösen Sie über eine Matrixformel:

=SUMME((LÄNGE(Bereich)-LÄNGE
WECHSELN(Bereich;Wort;"")))/LÄNGE(Wort))

Bestätigen Sie die Matrixformel nach der Eingabe über die Tastenkombination „Strg“,“Shift“,“Enter“.

1. Mit „Bereich" übergeben Sie den Zellbereich, in dem Sie ein Wort zählen möchten.
2. Über „Wort" legen Sie den Begriff fest, den Sie zählen möchten.
3. Die Formel zählt exakt die übergebene Zeichenkette, auch wenn diese sich innerhalb eines Wortes befindet. Groß- und Kleinschreibung wird dabei beachtet.

Und so arbeitet Ihre neue Formel:

• Über die WECHSELN-Funktion ersetzen Sie in jeder Zelle des übergebenen Bereichs das zu zählende Wort durch nichts.
• Diese verringerte Anzahl an Zeichen zählen Sie für jede Zelle des Bereichs und ziehen sie von der Länge der unveränderten Inhalte aus dem Bereich ab.
• Aus diesen Differenzen bilden Sie mit SUMME die Summe.
• Als Ergebnis erhalten Sie die Summe der Zeichen aller enthaltenen gesuchten Worte.
• Indem Sie diese Summe der Zeichen durch die Anzahl der Zeichen ebendieses Inhalts teilen, erhalten Sie als Ergebnis exakt die Anzahl des Auftretens des gesuchten Worts.

PS: Qualitätsmanagement ist uns wichtig!

Bitte teilen Sie uns mit, wie Ihnen unser Beitrag gefällt. Klicken Sie hierzu auf die unten abgebildeten Sternchen (5 Sternchen = sehr gut):

In diesem Artikel werde ich ihnen zeigen, wie man in Excel bestimmte Zeichen in einer Zelle zählen kann. Natürlich kann man diese Formel dann nicht nur auf Zellen, sondern auch auf ganze Zeilen oder Spalten anwenden.

Mithilfe der Formeln die Sie nun kennenlernen, werden Sie zum Beispiel anschließend auch wissen, wie man ganz einfach die Anzahl an einem bestimmten Zeichen im Text herausfinden kann, wenn dieser in einer gesonderten Zelle steht. Alles was Sie dazu benötigen, ist eine der gleich aufgeführten Formeln. Welche Sie benutzen, hängt von ihren Bedürfnissen ab.

Inhalt

• 1 Beginn:
• 2 Groß- und Kleinbuchstaben zählen (Matrixformel):
  • 2.1 Ein Zeichen mit einer Matrixformel:
  • 2.2 Ein Zeichen ohne Matrixformel:
  • 2.3 Mehrere Zeichen mit Matrixformel:
  • 2.4 Mehrere Zeichen ohne Matrixformel:
• 3 Nur Kleinbuchstaben zählen:
• 4 Mehrere Zellen untersuchen:

Beginn:

Zu aller Erst müssen Sie in die Excel Tabelle natürlich die Wörter oder den Text hineinschreiben, in dem die Anzahl an bestimmten Zeichen ausgegeben werden soll. Wollen Sie der Anleitung genau folgen und am besten auch die gleichen Formeln wie ich verwenden, so schreiben Sie ihren Text in die Spalte A und die Formeln dann in Spalte B. Ich habe für mein Beispiel das Wort „Popokatepetel“ gewählt, welches dann also in Zelle A1 steht. Haben Sie ihre Strings eingetragen, gehen Sie zum nächsten Schritt weiter.

Groß- und Kleinbuchstaben zählen (Matrixformel):

Ein Zeichen mit einer Matrixformel:

Am Anfang möchte ich ihnen zeigen, wie Sie mit einer Formel die Anzahl an bestimmten, im String vorkommenden, Zeichen ausgeben können, wenn es dabei egal ist, ob der Buchstabe groß- oder kleingeschrieben wird. Für die Berechnung nehmen Sie einfach die Zelle rechts vom Wort oder dem Text, also die Zelle B1. Wie man an der Überschrift des Punktes schon erkennen kann, wird hier eine Matrixformel verwendet. Schreiben Sie deshalb nun in die gewünschte Zelle folgendes:

=SUMME((TEIL(A1;SPALTE(1:1);1)="p")*1)

Wie schon gesagt, ist das eine Matrixformel. Das bedeutet, dass Sie die Formel nicht einfach so ausführen können, sondern Sie müssen jetzt erst nochmal die Zelle anklicken. Haben Sie das gemacht, so klicken Sie oben auch noch in die Bearbeitungszeile der Formel. Jetzt drücken Sie auf ihrer Tastatur gleichzeitig die Tasten STRG+SHIFT+Enter, wodurch die Matrixformel nun richtig ausgeführt wird. Das sehen Sie auch daran, dass nun in der Zelle der richtige Wert erschein. In meinem Fall wird hier „3“ angezeigt, da in dem Wort drei Mal der Buchstabe „P“ (oder „p“) vorkommt. Aber auch die Formel hat sich verändert, sie sieht nun so aus:

{=SUMME((TEIL(A1;SPALTE(1:1);1)="p")*1)}

Möchten Sie nicht nach dem Buchstaben „p“ suchen, so ändern Sie die Formel einfach entsprechend ab. Dabei müssen Sie nicht zwingend einen Buchstaben nehmen, sondern es kann auch ein anderes Zeichen sein.

(Zur Darstellung in Originalgröße Abbildungen anklicken)

Ein Zeichen ohne Matrixformel:

Wie sooft kann man eine Möglichkeit auch ohne Matrixformel darstellen, wenn eine möglich ist. So auch in diesem Fall. Löschen Sie nun den aktuellen Inhalt der Zelle B1 oder eben der Zelle, in der die Ausgabe erfolgen soll.  Um die Anzahl an bestimmten Zeichen (egal ob groß- oder kleingeschrieben) in der Zelle A1 zu bekommen, müssen Sie die folgende Formel eingeben:

=LÄNGE(A1)-LÄNGE(WECHSELN(KLEIN(A1);"p";))

Da diese keine Matrixformel ist, wird das Ergebnis sofort angezeigt, nachdem Sie die Formel eingegeben haben. Haben sie den Schritt von gerade eben auch gemacht, so werden Sie hier nun das gleiche Ergebnis wie bei der Matrixformel sehen, bei mir also immer noch die „3“. Auch hier suchen Sie wieder nach einem anderen Zeichen, indem Sie den Buchstaben „p“ in der Formel entsprechend verändern.

Mehrere Zeichen mit Matrixformel:

Jetzt wissen Sie über die zwei Möglichkeiten Bescheid, wie man die Anzahl an Zeichen wiedergibt, wenn nur nach einem Zeichen gesucht wird. Sucht man aber nach mehreren Zeichen, so wird man mit dieser Formel nicht weit kommen, dafür benötigen Sie dann wieder eine neue. Auch hier gibt es wieder die Variante mit und die Variante ohne Matrixformel. Zuerst werde ich die Lösung mit der Matrixformel behandeln. Löschen Sie dazu erst einmal den Inhalt der Zelle B1 oder der, in der die Ausgabe erscheinen soll. Anschließend geben Sie hier nun folgendes ein:

=SUMME((TEIL(A1;SPALTE(1:1);1)={"p";"t"})*1)

Wie schon gesagt, ist das eine Matrixformel. Also müssen Sie zuerst die Zelle wieder anklicken und anschließend noch in die Bearbeitungszeile der Formel. Haben Sie das gemacht, so drücken Sie nun STRG+SHIFT+Enter. Nun wird in der Zelle der richtige Wert angezeigt. Bei mir war es die Zahl „5“, da ich die Zelle A1 nach den Buchstaben „p“ und „t“ durchsucht habe. Desweiteren hat sich aber auch die Formel verändert, sie sieht nun so aus:

{=SUMME((TEIL(A1;SPALTE(1:1);1)={"p";"t"})*1)}

Möchten Sie nicht nach den Buchstaben „p“ und „t“ suchen, so ändern Sie die Formel einfach entsprechend ab. Natürlich müssen Sie auch überhaupt nicht nach Buchstaben suchen, es kann auch ein anderes Zeichen, wie zum Beispiel eine Zahl sein. Möchten Sie nach mehreren Zeichen suchen, so ist auch das kein Problem, dazu müssen Sie in der Formel in der geschweiften Klammer einfach noch folgendes hinzufügen (natürlich angepasst):
;“Zeichen“

Mehrere Zeichen ohne Matrixformel:

Wie ich schon gesagt habe, kann man die Anzahl von mehreren Zeichen auch so rausbekommen, indem man keine Matrixformel verwendet. Löschen Sie dazu erst einmal wieder den Inhalt von B1 und anschließend geben Sie hier folgendes ein:

=LÄNGE(A1)-LÄNGE(WECHSELN(WECHSELN(KLEIN(A1);"p";);"t";))

Diese Formel liefert sofort das Ergebnis, nachdem Sie sie eingetragen haben. Ausgegeben wird nun auch hier korrekterweise die Anzahl an den Zeichen „p“ und „t“ in der Zelle A1. Suchen Sie nach anderen Zeichen, so verändern Sie „p“ und „t“ entsprechend, desweiteren können Sie auch ganz leicht ein neues Zeichen hinzufügen. Steht ihr zu durchsuchender String nicht in der Zelle A1, so ändern Sie diesen Zellbezug einfach zwei Mal ab.

Nur Kleinbuchstaben zählen:

Die bisherigen Anleitungen haben sich alle darauf bezogen, dass nach Groß- und nach Kleinbuchstaben gesucht wird. Möchten Sie aber, dass nur nach Kleinbuchstaben gesucht wird, so benötigen Sie hierfür natürlich wieder eine neue Formel. Um Sie einzutragen, entfernen Sie erst einmal die alte Formel aus der Zelle B1. Nun tragen Sie hier folgendes ein:

=LÄNGE(A1)-LÄNGE(WECHSELN(A1;"p";))

Auch diese Formel ist keine Matrixformel, das heißt, dass das Ergebnis ohne weitere Maßnahmen angezeigt wird. In meinem Beispiel ist alles richtig abgelaufen und es wird die „2“ angezeigt, da in dem Wort „Popokatepetel“ zwei kleine „p“-s vorkommen. Möchten Sie nach einem anderen Zeichen suchen, so ändern Sie das „p“ in der Formel einfach entsprechend ab. Auch die Zellbezüge müssen Sie gegebenenfalls korrigieren.

Mehrere Zellen untersuchen:

Nun wissen Sie, wie man die Anzahl eines bestimmten Zeichens pro Zelle herausbekommt. Möchten Sie nun aber, dass ein Zellbereich untersucht wird, so haben Sie mit dieser Formel Probleme. Dafür gibt es aber in Form einer anderen Formel eine Lösung. Löschen Sie nun die Zelle B1 und tragen Sie die folgende Formel ein:

=SUMMENPRODUKT(LÄNGE(A1:A99)-LÄNGE(WECHSELN(KLEIN(A1:A99);"p";)))

Auch das ist keine Matrixformel, was heißt, dass das Ergebnis unverzüglich angezeigt wird. In meinem Fall also nun die Zahl „6“, da zwei Mal das Wort „Popokatepetel“ untersucht wird, welches jeweils drei „p“-s besitzt. Suchen Sie ein anderes Zeichen, ändern Sie die Formel einfach entsprechend um. In diesem Fall ist es wichtig, die Formel wirklich nicht in die Spalte A zu schreiben, da sonst eine Fehlermeldung erscheinen würde und Sie die Zellbezüge noch verändern müssten.

Nun wissen Sie über alle Möglichkeiten Bescheid die Anzahl an bestimmten Zeichen pro Zelle oder pro Zellbereich auszugeben. Dabei ist es egal, ob Sie eine Matrixformel oder keine verwenden. Mit dem zuletzt aufgeführten Tipp können Sie außerdem auch ganze Zeilen oder Spalten durchsuchen.

Wie oft kommt ein Zeichen in einer Zelle vor?

Wie oft kommt ein Wert in einer Spalte vor Excel?

Wie oft ist ein Wert vorhanden Excel?

Wie viele Zeichen gehen in eine Excel Zelle?